import dev.firstdark.keymaster.tasks.SignJarTask

plugins {
    id 'java'
    id "dev.firstdark.keymaster"
}

group = 'dev.firstdark.keymastertest'
version = '1.0.0'

repositories {
    mavenCentral()
}

dependencies {

}

// This is optional. These values can be configured on the task
keymaster {
    // GPG Password
    gpgPassword = "123456"
    // GPG Key file, or String.
    gpgKey = System.getenv("GPG_KEY")
    // Generate a .sig file for signed jars, to be used for verification
    generateSignature = true
}

tasks.register('createDummyJar', Jar) {
    // Configure the JAR task to have no files
    from {}
    archiveFileName = 'dummy.jar' // Set the desired name for the JAR file
}

// Register a custom task to sign your jar
tasks.register('signJar', SignJarTask) {
    // Depend on the task used to build your project
    dependsOn jar

    // The input artifact. This can be a Task, File or File Name
    artifactInput = jar

    // Optional. Set the output name of the signed jar. This defaults to the artifactInput file name, and will overwrite it
    outputFileName = "testsign"

    // GPG Private key file or string. Not required when the extension is used
    gpgKey = System.getenv("GPG_KEY")

    // GPG Private Key password. Not required when extension is used
    gpgPassword = "123456"

    // Should the task generate a .sig file. Defaults to true, and not required when extension is used
    generateSignature = false
}